first commit

2021-09-06 19:35:04 +02:00
commit 2e47148476
17 changed files with 638 additions and 0 deletions
@@ -0,0 +1,53 @@
+plugins {
+    `java-library`
+    id("com.github.johnrengelman.shadow") version "7.0.0"
+}
+
+allprojects {
+    val build = System.getenv("BUILD_NUMBER") ?: "SNAPSHOT"
+    group = "com.alttd.boosters"
+    version = "1.0.0-BETA-$build"
+    description = "Easily manage all boosters on the Altitude Minecraft Server Network."
+}
+
+subprojects {
+    apply<JavaLibraryPlugin>()
+
+    java {
+        toolchain {
+            languageVersion.set(JavaLanguageVersion.of(16))
+        }
+    }
+
+    tasks {
+        withType<JavaCompile> {
+            options.encoding = Charsets.UTF_8.name()
+        }
+
+        withType<Javadoc> {
+            options.encoding = Charsets.UTF_8.name()
+        }
+    }
+}
+
+dependencies {
+    implementation(project(":boosters-api"))
+    implementation(project(":plugin"))
+    implementation(project(":velocity"))
+    implementation("net.kyori", "adventure-text-minimessage", "4.1.0-SNAPSHOT")
+}
+
+tasks {
+
+    shadowJar {
+        archiveFileName.set("${project.name}-${project.version}.jar")
+        listOf(
+            "net.kyori.adventure.text.minimessage"
+        ).forEach { relocate(it, "${rootProject.group}.lib.$it") }
+    }
+
+    build {
+        dependsOn(shadowJar)
+    }
+
+}