plugins {
    java
    id("org.openapi.generator") version "7.12.0"
}

group = "com.alttd.chat"
version = "2.0.0-SNAPSHOT"

dependencies {
    implementation("io.swagger.core.v3:swagger-annotations:2.2.28")

    implementation("com.squareup.okhttp3:okhttp:4.12.0")
    implementation("com.squareup.okhttp3:logging-interceptor:4.12.0")

    implementation("com.google.code.gson:gson:2.12.1")
    implementation("io.gsonfire:gson-fire:1.9.0")

    implementation("javax.annotation:javax.annotation-api:1.3.2")
    implementation("jakarta.annotation:jakarta.annotation-api:2.1.1")
}

sourceSets {
    main {
        java {
            srcDir("${projectDir}/build/generated-sources/client/src/main/java")
        }
    }
}

tasks.named<org.openapitools.generator.gradle.plugin.tasks.GenerateTask>("openApiGenerate") {
    generatorName.set("java")
    inputSpec.set("${projectDir}/src/main/resources/chat-api.yml")
    configFile.set("${projectDir}/src/main/resources/config_backend.json")
    outputDir.set("${projectDir}/build/generated-sources/client")

    apiPackage.set("com.alttd.altitudeweb.api")
    modelPackage.set("com.alttd.altitudeweb.model")

    modelNameSuffix.set("Dto")

    additionalProperties.set(
        mapOf(
            "dateLibrary" to "java8",
            "library" to "okhttp-gson"
        )
    )

    generateApiTests.set(false)
    generateApiDocumentation.set(false)
    generateModelTests.set(false)
    generateModelDocumentation.set(false)

    generateAliasAsModel.set(true)
}

sourceSets {
    main {
        java {
            srcDir(layout.buildDirectory.dir("generated/openapi/src/main/java"))
        }
    }
}

tasks.compileJava {
    dependsOn("openApiGenerate")
}