plugins {
    `maven-publish`
    id("net.minecrell.plugin-yml.bukkit") version "0.6.0"
}

dependencies {
    implementation(project(":api")) // API
    compileOnly("com.alttd:Comet-API:1.20.4-R0.1-SNAPSHOT") {
        isChanging = true
    }

    compileOnly("org.projectlombok:lombok:1.18.24")
    annotationProcessor("org.projectlombok:lombok:1.18.24")

    testImplementation("org.junit.jupiter:junit-jupiter-api:5.8.1")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.8.1")
}

tasks {
    jar {
        archiveFileName.set("${rootProject.name}-${project.name}.jar")
    }

    test {
        useJUnitPlatform()
    }
}

bukkit {
    name = rootProject.name
    main = "$group.${rootProject.name}Plugin"
    version = "${rootProject.version}"
    apiVersion = "1.20"
    authors = listOf("destro174")
    load = net.minecrell.pluginyml.bukkit.BukkitPluginDescription.PluginLoadOrder.POSTWORLD

    commands {
        register("island") {
            description = "Teleports you to your island. Creates a new island if it is not existing."
            aliases = listOf("is")
            permission = "${rootProject.name}.command.island"
        }

        register("challenges") {
            description = "Opens the challenges menu."
            aliases = listOf("ch")
            permission = "${rootProject.name}.command.island"
        }

        register("skyblock") {
            description = "${rootProject.name} admin command."
            permission = "${rootProject.name}.command.admin"
        }

        register("kickfrombungee") {
            description = "${rootProject.name} admin command."
        }
    }
}