Drop maven, get Gradle

build.gradle.kts

@@ -0,0 +1,52 @@
+import com.github.jengelman.gradle.plugins.shadow.tasks.ConfigureShadowRelocation
+
+plugins {
+    id("java")
+    id("com.github.johnrengelman.shadow") version "7.1.0"
+}
+
+group = "com.alttd"
+version = "1.0.0-SNAPSHOT"
+description = "Altitude Villager Shop plugin."
+
+apply<JavaLibraryPlugin>()
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(17))
+    }
+}
+
+tasks {
+    withType<JavaCompile> {
+        options.encoding = Charsets.UTF_8.name()
+    }
+
+    withType<Javadoc> {
+        options.encoding = Charsets.UTF_8.name()
+    }
+
+    shadowJar {
+        dependsOn(getByName("relocateJars") as ConfigureShadowRelocation)
+        archiveFileName.set("${project.name}-${project.version}.jar")
+        minimize()
+        configurations = listOf(project.configurations.shadow.get())
+    }
+
+    build {
+        dependsOn(shadowJar)
+    }
+
+    create<ConfigureShadowRelocation>("relocateJars") {
+        target = shadowJar.get()
+        prefix = "${project.name}.lib"
+    }
+}
+
+dependencies {
+    compileOnly("com.alttd:Galaxy-API:1.18.1-R0.1-SNAPSHOT")
+    compileOnly("com.github.milkbowl:VaultAPI:1.7") {
+        exclude("org.bukkit","bukkit")
+    }
+    shadow("org.apache.commons:commons-math3:3.2")
+}